"small b";

charcode:=142;

e:=nulledges;

lhsb:=sidebearing_straight;rhsb:=sidebearing_curved;

numeric x[],y[];			% reference edges

x11=lhsb+bowl_stroke_weight;		% inner left-hand edge of bowl

x1=lhsb+ascender_weight;		% bowl reference edge

x14=lhsb+bowl_stroke_separation_b;	% inner right-hand edge

x4=x14+vertical_curve_weight;		% outer

width:=x4+rhsb;				% character width

widthbox(width);


y1=upper_setback_height;		% bottom of ascender

y7=lower_arch_spring_height_a;		% bottom of vertical

top:=(lhsb,ascender_line);
draw vertical(top,y1,ascender_weight,right);	% ascender

top:=(lhsb,y1);
draw vertical(top,y7,stroke_weight,right);	% vertical in bowl

top:=(lhsb,ascender_line);
draw serif(upper_external_serif_length,left,top);

					% upper serif
pair p[];

p1=(lhsb,y7);
p2=(lhsb,baseline);
p3=(0.4[lhsb,x11],baseline);
p4=(x11,y7);

draw ((p1..p2 & p2..p3 &
       p3..p4 & p4..p1 & cycle)
      if slant_switch then slanted slant fi
     );					% lower terminal


numeric skew;skew=1 hsmm;

draw p_bowl(z1,x11,(x14-x11),baseline-overshoot,y7,skew);

if ddisplay then showit fi;

shipit;